Feat: Gradle Version Catalog

build.gradle.kts

@@ -1,5 +1,5 @@
 plugins {
-    id("fabric-loom") version "1.11-SNAPSHOT"
+    alias(libs.plugins.fabric.loom)
     id("maven-publish")
 }
 
@@ -13,7 +13,7 @@ base {
         "local"
     }
 
-    version = properties["minecraft_version"] as String + "-" + suffix
+    version = libs.versions.minecraft.get() + "-" + suffix
 }
 
 repositories {
@@ -71,35 +71,34 @@ configurations {
 
 dependencies {
     // Fabric
-    minecraft("com.mojang:minecraft:${properties["minecraft_version"] as String}")
-    mappings("net.fabricmc:yarn:${properties["yarn_mappings"] as String}:v2")
-    modImplementation("net.fabricmc:fabric-loader:${properties["loader_version"] as String}")
+    minecraft(libs.minecraft)
+    mappings(variantOf(libs.yarn) { classifier("v2") })
+    modImplementation(libs.fabric.loader)
 
-    modInclude(fabricApi.module("fabric-api-base", properties["fapi_version"] as String))
-    modInclude(fabricApi.module("fabric-resource-loader-v0", properties["fapi_version"] as String))
-    modInclude(fabricApi.module("fabric-resource-loader-v1", properties["fapi_version"] as String))
+    val fapiVersion = libs.versions.fabric.api.get()
+    modInclude(fabricApi.module("fabric-api-base", fapiVersion))
+    modInclude(fabricApi.module("fabric-resource-loader-v0", fapiVersion))
+    modInclude(fabricApi.module("fabric-resource-loader-v1", fapiVersion))
 
     // Compat fixes
-    modCompileOnly(fabricApi.module("fabric-renderer-indigo", properties["fapi_version"] as String))
-    modCompileOnly("maven.modrinth:sodium:${properties["sodium_version"] as String}") { isTransitive = false }
-    modCompileOnly("maven.modrinth:lithium:${properties["lithium_version"] as String}") { isTransitive = false }
-    modCompileOnly("maven.modrinth:iris:${properties["iris_version"] as String}") { isTransitive = false }
-    modCompileOnly("com.viaversion:viafabricplus:${properties["viafabricplus_version"] as String}") { isTransitive = false }
-    modCompileOnly("com.viaversion:viafabricplus-api:${properties["viafabricplus_version"] as String}") { isTransitive = false }
-
-    // Baritone (https://github.com/MeteorDevelopment/baritone)
-    modCompileOnly("meteordevelopment:baritone:${properties["baritone_version"] as String}-SNAPSHOT")
-    // ModMenu (https://github.com/TerraformersMC/ModMenu)
-    modCompileOnly("com.terraformersmc:modmenu:${properties["modmenu_version"] as String}")
-
-    // Libraries
-    jij("meteordevelopment:orbit:${properties["orbit_version"] as String}")
-    jij("org.meteordev:starscript:${properties["starscript_version"] as String}")
-    jij("meteordevelopment:discord-ipc:${properties["discordipc_version"] as String}")
-    jij("org.reflections:reflections:${properties["reflections_version"] as String}")
-    jij("io.netty:netty-handler-proxy:${properties["netty_version"] as String}") { isTransitive = false }
-    jij("io.netty:netty-codec-socks:${properties["netty_version"] as String}") { isTransitive = false }
-    jij("de.florianmichael:WaybackAuthLib:${properties["waybackauthlib_version"] as String}")
+    modCompileOnly(fabricApi.module("fabric-renderer-indigo", fapiVersion))
+    modCompileOnly(libs.sodium) { isTransitive = false }
+    modCompileOnly(libs.lithium) { isTransitive = false }
+    modCompileOnly(libs.iris) { isTransitive = false }
+    modCompileOnly(libs.viafabricplus) { isTransitive = false }
+    modCompileOnly(libs.viafabricplus.api) { isTransitive = false }
+
+    modCompileOnly(libs.baritone)
+    modCompileOnly(libs.modmenu)
+
+    // Libraries (JAR-in-JAR)
+    jij(libs.orbit)
+    jij(libs.starscript)
+    jij(libs.discord.ipc)
+    jij(libs.reflections)
+    jij(libs.netty.handler.proxy) { isTransitive = false }
+    jij(libs.netty.codec.socks) { isTransitive = false }
+    jij(libs.waybackauthlib)
 }
 
 // Handle transitive dependencies for jar-in-jar
@@ -152,8 +151,8 @@ tasks {
             "version" to project.version,
             "build_number" to buildNumber,
             "commit" to commit,
-            "minecraft_version" to project.property("minecraft_version"),
-            "loader_version" to project.property("loader_version")
+            "minecraft_version" to libs.versions.minecraft.get(),
+            "loader_version" to libs.versions.fabric.loader.get()
         )
 
         inputs.properties(propertyMap)
@@ -215,7 +214,7 @@ publishing {
             from(components["java"])
             artifactId = "meteor-client"
 
-            version = properties["minecraft_version"] as String + "-SNAPSHOT"
+            version = libs.versions.minecraft.get() + "-SNAPSHOT"
         }
     }
 

gradle.properties

@@ -1,50 +1,6 @@
 org.gradle.jvmargs=-Xmx2G
 org.gradle.configuration-cache=false
 
-# Fabric (https://fabricmc.net/develop)
-minecraft_version=1.21.10
-yarn_mappings=1.21.10+build.1
-loader_version=0.17.2
-fapi_version=0.135.0+1.21.10
-
 # Mod Properties
 maven_group=meteordevelopment
 archives_base_name=meteor-client
-
-# Dependency Versions
-
-# Baritone (https://github.com/MeteorDevelopment/baritone)
-baritone_version=1.21.10
-
-# Sodium (https://github.com/CaffeineMC/sodium-fabric)
-sodium_version=mc1.21.10-0.7.2-fabric
-
-# Lithium (https://github.com/CaffeineMC/lithium-fabric)
-lithium_version=mc1.21.10-0.20.0-fabric
-
-# Iris (https://github.com/IrisShaders/Iris)
-iris_version=1.9.6+1.21.10-fabric
-
-# ModMenu (https://github.com/TerraformersMC/ModMenu)
-modmenu_version=15.0.0
-
-# Orbit (https://github.com/MeteorDevelopment/orbit)
-orbit_version=0.2.4
-
-# Starscript (https://github.com/MeteorDevelopment/starscript)
-starscript_version=0.2.5
-
-# DiscordRPC (https://github.com/MeteorDevelopment/java-discord-rpc)
-discordipc_version=1.1
-
-# Reflections (https://github.com/ronmamo/reflections)
-reflections_version=0.10.2
-
-# Netty (https://github.com/netty/netty)
-netty_version=4.1.118.Final
-
-# ViaFabricPlus (https://github.com/ViaVersion/ViaFabricPlus)
-viafabricplus_version=4.3.1
-
-# WaybackAuthLib (https://github.com/FlorianMichael/WaybackAuthLib)
-waybackauthlib_version=1.0.1

gradle/libs.versions.toml

@@ -0,0 +1,63 @@
+[versions]
+# Fabric (https://fabricmc.net/develop)
+minecraft = "1.21.10"
+yarn-mappings = "1.21.10+build.2"
+fabric-loader = "0.17.3"
+fabric-api = "0.136.0+1.21.10"
+
+# Plugins
+# Loom (https://github.com/FabricMC/fabric-loom)
+loom = "1.12-SNAPSHOT"
+
+# Mods
+# Baritone (https://github.com/MeteorDevelopment/baritone)
+baritone = "1.21.10-SNAPSHOT"
+# Sodium (https://github.com/CaffeineMC/sodium-fabric)
+sodium = "mc1.21.10-0.7.2-fabric"
+# Lithium (https://github.com/CaffeineMC/lithium-fabric)
+lithium = "mc1.21.10-0.20.0-fabric"
+# Iris (https://github.com/IrisShaders/Iris)
+iris = "1.9.6+1.21.10-fabric"
+# ModMenu (https://github.com/TerraformersMC/ModMenu)
+modmenu = "15.0.0"
+# Orbit (https://github.com/MeteorDevelopment/orbit)
+orbit = "0.2.4"
+# Starscript (https://github.com/MeteorDevelopment/starscript)
+starscript = "0.2.5"
+# DiscordRPC (https://github.com/MeteorDevelopment/java-discord-rpc)
+discordipc = "1.1"
+# Reflections (https://github.com/ronmamo/reflections)
+reflections = "0.10.2"
+# Netty (https://github.com/netty/netty)
+netty = "4.1.118.Final"
+# ViaFabricPlus (https://github.com/ViaVersion/ViaFabricPlus)
+viafabricplus = "4.3.1"
+# WaybackAuthLib (https://github.com/FlorianMichael/WaybackAuthLib)
+waybackauthlib = "1.0.1"
+
+[libraries]
+# Fabric base
+minecraft = { module = "com.mojang:minecraft", version.ref = "minecraft" }
+yarn = { module = "net.fabricmc:yarn", version.ref = "yarn-mappings" }
+fabric-loader = { module = "net.fabricmc:fabric-loader", version.ref = "fabric-loader" }
+
+# Mods
+sodium = { module = "maven.modrinth:sodium", version.ref = "sodium" }
+lithium = { module = "maven.modrinth:lithium", version.ref = "lithium" }
+iris = { module = "maven.modrinth:iris", version.ref = "iris" }
+baritone = { module = "meteordevelopment:baritone", version.ref = "baritone" }
+modmenu = { module = "com.terraformersmc:modmenu", version.ref = "modmenu" }
+viafabricplus = { module = "com.viaversion:viafabricplus", version.ref = "viafabricplus" }
+viafabricplus-api = { module = "com.viaversion:viafabricplus-api", version.ref = "viafabricplus" }
+
+# Libraries
+orbit = { module = "meteordevelopment:orbit", version.ref = "orbit" }
+starscript = { module = "org.meteordev:starscript", version.ref = "starscript" }
+discord-ipc = { module = "meteordevelopment:discord-ipc", version.ref = "discordipc" }
+reflections = { module = "org.reflections:reflections", version.ref = "reflections" }
+netty-handler-proxy = { module = "io.netty:netty-handler-proxy", version.ref = "netty" }
+netty-codec-socks = { module = "io.netty:netty-codec-socks", version.ref = "netty" }
+waybackauthlib = { module = "de.florianmichael:WaybackAuthLib", version.ref = "waybackauthlib" }
+
+[plugins]
+fabric-loom = { id = "fabric-loom", version.ref = "loom" }

gradle/wrapper/gradle-wrapper.properties

@@ -1,6 +1,6 @@
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-9.1.0-bin.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-9.2.0-bin.zip
 networkTimeout=10000
 validateDistributionUrl=true
 zipStoreBase=GRADLE_USER_HOME

settings.gradle.kts

@@ -9,4 +9,6 @@ pluginManagement {
     }
 }
 
+rootProject.name = "meteor-client"
+
 include("launch")